#compdef pkgcheck

SHELL_LIB=$(python -c 'import pkgcore._const as const; print(const.LIBDIR_PATH)')/shell/zsh/pkgcore.zsh
source "${SHELL_LIB}" || print "$0: failed to load '${SHELL_LIB}'" >&2
unset SHELL_LIB

typeset -a common_main_args common_output_args common_args

common_main_args=(
  '(- :)'--version'[show version information and exit]'
  '--add-config[modify an existing configuration section]'
  '--new-config[add a new configuration section]'
  '--empty-config[do not load user/system configuration]'
  '--config[override location of config files]:config path:_files'
  "--color[Color output]:yes/no:((y\:'yes' n\:'no'))"
)

common_output_args=(
  '(- :)'{-h,--help}'[show help information and exit]'
  '(--debug --help -h)--debug[enable debugging output]'
  '(--quiet -q --verbose -v)'{-q,--quiet}'[suppress non-error output]'
  '(--verbose -v --quiet -q)'{-v,--verbose}'[show verbose output]'
)

common_args=(
  $common_main_args
  $common_output_args
)

local curcontext=$curcontext state state_descr line ret=1
typeset -a options

options=(
  '--list-checks[print what checks are available to run and exit]'
  '--list-reporters[print known reporters]'
  {'(--repo)-r','(-r)--repo'}'[repo to pull packages from]:repo:_repos'
)

_arguments -C \
  $common_args \
  $options \
  && ret=0

return ret

# vim: set et sw=2 ts=2 ft=zsh:
